World of Ruin Dance backgrounds patch

[seibaby]

Here's a neat little hack that adds more flavour to the Dance command. When you reach the World of Ruin, Dance will change the battlefield backgrounds into their WoR counterparts instead of the World of Balance backgrounds.

Wind Song: Dry land
Forest Nocturne: Brown forest
Desert Aria: Desert (WoR)
Love Sonata: Fanatic's Tower interior
Earth Blues: Kefka's Tower exterior
Water Rondo: (unchanged)
Dusk Requem: Blue/Purple caves (note: if you prefer the fiery red of the Phoenix Cave, change it to $2A!)
Snowman Jazz: (unchanged)

This patch only uses free space in bank D1 - it should be compatible with most other patches.

Download

Code:
[spoiler]

Code:

; World of Ruin battle backgrounds for Dance
; by Seibaby
; v1.0 - Initial version (2018/10/03)

;xkas 0.06
hirom
;header
!freespace = $D1F9D0

; Hook
org $C217A3
JSL setDanceBG

; Table of WoR backgrounds associated with each Dance
org $D1F9A3
reset bytes
worDanceTable:
db $05 ; World of Ruin (Wind Song)
db $01 ; Brown Forest (Forest Nocturne)
db $2F ; Desert, WoR (Desert Aria)
db $04 ; Fanatic's Interior (Love Sonata)
db $16 ; Kefka's Domain Exterior (Earth Blues)
db $23 ; Underwater (Water Rondo)
db $11 ; Blue/Purple Cave (Dusk Requiem)
db $12 ; Icy Field (Snowman Jazz)

wobDanceTable:
db $00 ; Grass (Wind Song)
db $03 ; Green Forest (Forest Nocturne)
db $02 ; Desert, WoB (Desert Aria)
db $2B ; Light Building (Love Sonata)
db $0B ; Mountain Top (Earth Blues)
db $23 ; Underwater (Water Rondo)
db $0A ; Brown Cave (Dusk Requiem)
db $12 ; Icy Field (Snowman Jazz)

; for reference, see
; https://www.ff6hacking.com/wiki/doku.php?id=ff3:ff3us:doc:asm:list:battle_backgrounds

org !freespace
reset bytes
setDanceBG:
        LDA $1E94           ; Event flags
        BIT #$10            ; Are we in the WoR?
        BNE .wor            ; If so, change the Dance BG
.wob    LDA wobDanceTable,X ; Get default background for this Dance
        RTL
.wor    LDA worDanceTable,X ; Get associated WoR background
        RTL
print bytes," bytes written"

[/spoiler]

[madsiur]

This is a neat improvement! Now I want a "++" version where all dance move have their own background according to the spirit, symbolism, name mythology and nature of the attack.

[Tenkarider]

btw, what's the ASM trigger(actual code) that makes shift from WoB dance BG to WoR dance BG?

[madsiur]

btw, what's the ASM trigger(actual code) that makes shift from WoB dance BG to WoR dance BG?

Have you looked at his code a bit? The famous WoR bit, first 2 lines of actual code:

Code:

LDA $1E94           ; Event flags
BIT #$10            ; Are we in the WoR?

[ATMA]

Very cool patch.  I like the thinking behind using WoR backgrounds.
I have a question related to this,  but not directly.  First, I feel I should mention that I mostly have been using FF3usME and FF6AE for most my customizing, as well as a few patches and a bit of hex editing.  Obviously we are able to change the backgrounds used by Dance, but is there a way to have it not change the background at all?
I know it's kind of the Geomancer command, but I'd prefer it behave more of a Dancer/Performer.  Having an epic battle that's all set up in a dark or serious mood, then suddenly having a bright sunny background kind of kills the ambiance.
My grasp of coding and modding is very limited, but this seems like something that should be possible.

[seibaby]

Yup, here's the code for the Dance command:

Code:

Dance

C2/177D: B9 F8 3E     LDA $3EF8,Y
C2/1780: 09 01        ORA #$01
C2/1782: 99 F8 3E     STA $3EF8,Y    (Set Dance status)
C2/1785: A9 FF        LDA #$FF
C2/1787: 85 B7        STA $B7        (default animation to not affecting background)
C2/1789: B9 E1 32     LDA $32E1,Y    (Which dance is selected for this character)
C2/178C: 10 06        BPL $1794      (branch if already defined)
C2/178E: AD 6F 3A     LDA $3A6F      (if not, read a "global" dance variable set
                                      by last character to choose Dance)
C2/1791: 99 E1 32     STA $32E1,Y    (and save it as this character's dance)
C2/1794: AE E2 11     LDX $11E2
C2/1797: DF 5B 8E ED  CMP $ED8E5B,X  (Check if current background is associated with
                                      this dance)
C2/179B: F0 A4        BEQ $1741      (Branch if it is)
C2/179D: 20 53 4B     JSR $4B53      (random, 0 or 1 in Carry)
C2/17A0: 90 0D        BCC $17AF      (50% chance of branch and stumble)
C2/17A2: AA           TAX
C2/17A3: BF AB F9 D1  LDA $D1F9AB,X  (get default background for this Dance)
C2/17A7: 85 B7        STA $B7        (set it in animation)
C2/17A9: 8D E2 11     STA $11E2      (and change current background to it)
C2/17AC: 4C 41 17     JMP $1741      (BRA $1741?)

Look at C2/17A3 - C2/17AB. You'll want to replace those bytes with NOP (hex opcode: EA) using your hex editor. Or you can just overwrite the code at C2/17A3 with JMP $1741 (4C 41 17).

[SSJ Rick]

this is a really cool patch

[vico]

Is this compatible with C. V. Reynolds Bug-Fix Compilation and Script Fix?

[madsiur]

Is this compatible with C. V. Reynolds Bug-Fix Compilation and Script Fix?

I'm 99% sure that yes but you can verify with this:

http://l33t5k37ch3r.altervista.org/advan...inder.html

[vico]

Is this compatible with C. V. Reynolds Bug-Fix Compilation and Script Fix?

I'm 99% sure that yes but you can verify with this:

http://l33t5k37ch3r.altervista.org/advan...inder.html

Thanks a lot for share this website. I found the hacks there very useful!

Will try to combine some and see if doesnt crash!  Thanks again!