ASM Requests

Request: Pep Up change

I think it would be cool to have Pep Up work where the caster donates whatever HP/MP he currently has to the intended target and do what it normally does with the curing status effects, but instead of killing the caster it drops caster's HP and MP to 1. Then, if caster casts it again with 1 HP, it would donate nothing - or kill the caster, whichever is easier lol. But if caster regained some health, it would always donate whatever HP/MP the caster currently has and drop him to 1 HP/1 MP.

So I decided to take a whack at this tonight.

Spoiler (Click to View)

Code:

hirom   ; Don't change this
header  ; Comment out if your ROM has no header

; Alters the behavior of Pep Up thusly:
; It will reduce the user to 1 HP/MP and restore however much HP/MP s/he used to the target

org $C23E0D
DB $5A,$A6        ; Change Pep Up's pointer

org $C2A65A
STZ $3414        ; Set no damage modification
LDA $11A3
EOR #$80        ; Toggle concern MP
STA $11A3
BPL Heal_HP        ; Branch if concern MP is off - this will handle the HP healing portion
LDA $05,S        ; Get caster's battlefield ID
TAX
REP #$20        ; Set 16-bit A
LDA $3C08,X        ; Caster's current MP
DEC
STA $11B0        ; Save (caster's MP - 1) in damage
LDA #$0001
STA $3C08,X        ; Set caster's MP to 1
RTS

Heal_HP:
INC $3A70        ; Sets the attack to repeat, including special effect
LDA $05,S        ; Get caster's battlefield ID
TAX
REP #$20        ; Set 16-bit A
LDA $3BF4,X        ; Caster's current HP
DEC
STA $11B0        ; Save (caster's HP - 1) in damage
LDA #$0001
STA $3BF4,X        ; Set caster's HP to 1
RTS

; EOF

This hack changes Pep Up's pointer and uses free space at C2/A65A, since there was no way it would fit in Pep Up's old spot.

If used at 1 HP/MP, the caster will donate nothing.

There are some changes you'll need to make to the spell properties as well. Make sure it's not set to kill the caster anymore, and remove the (power * 100 / 16) flag. Its power needs to be greater than zero, but what it is specifically shouldn't matter (I typically set it to 1 in these cases). Also enable the "Concern MP" flag.

The start of the effect is similar (or identical, I guess) to Empowerer's, as it's the only other HP/MP dual effect skill I could think of.

The only issue I haven't worked out yet is preventing it from repeating Pep Up's "screen flash" animation. It's pretty subdued, so probably not a big deal, but the method that prevents Empowerer from repeating its animation doesn't seem to work here.

Edit: I also didn't test this with enemies using it, but I don't think there should be a problem.

Edit 2: It's also worth mentioning that I created this with the idea that Pep Up would have an MP cost. If it costs zero MP, I'll need to put a conditional branch in the MP-healing part to prevent it from recovering 9999 MP if the caster has 0 MP on use.